Positive monetary policy shock with nominal interest rate falling?

General DSGE Modeling
1

Hey folks,

i get very strange irf when i ran the following little monetary model. My problem is, when i look at the irf of U (the monetary shock) I would expect that when U rises R (the nominal interest rate) will also rise due to the standard taylor rule (R/Rss = (PI)^(jotaPI)*(Y/Yss)^(jotaY)*U;). But the opposite is the case. PLEASE WHERE IS THE MISTAKE?? Do I think wrong??

THE MODEL:

close all

var LAM R PI RK C W L Y A K MC B G U I RR TAX UTIL;
varexo eps_A eps_U eps_G;

parameters beta delta sigmaL omega alpha phiP Phi tau jotaR jotaPI jotaY rhoA rhoU rhoG sigmaA sigmaU sigmaG nu 
TAXss Gss Yss Rss sc AUX Kss Lss Css Wss Iss RKss LAMss Ass Uss Bss t TAXBAR;


beta = 0.90;
delta = 0.025; 
sigmaL = 5;
omega = 1;
alpha = 2/3;
phiP = 1.25;
Phi = 1.5;
tau = 5;
jotaR = 0;
jotaPI = 1.5;
jotaY = 0.125;
rhoA = 0.90;
rhoU = 0.90;
rhoG = 0.90;
sigmaA = 0.01;
sigmaU = 0.01;
sigmaG = 0.01;
nu = 0.8;
sc = 0.2;
t = 0.25;
AUX = ((1-alpha)*(1-1/Phi)/(1/beta - 1 + delta))^((1-alpha)/alpha);
Wss = AUX *alpha*(1-1/Phi);
Lss = ((1-sc-delta*AUX^(alpha/(1-alpha)))*sigmaL/(sigmaL-1)*omega*1/alpha*(1-1/Phi)^(-1))^(1/(-nu-1));
Kss = Lss*AUX^(1/(1-alpha));
Yss = Lss^(alpha)*Kss^(1-alpha);
Gss = sc*Yss;
Css = Yss - delta*Kss - Gss;
Rss = 1/beta;
TAXBAR = t; 
Bss = (sc*Yss-TAXBAR)/(1-Rss+tau);
TAXss = TAXBAR + tau*Bss;
Iss = delta*Kss;
RKss = 1/beta - 1 + delta;
LAMss = 1/Css;
Ass = 1;
Uss = 1;

model;
UTIL = log(C) -omega/(1+nu)*L^(1+nu);
LAM = beta*LAM(+1)*R/PI(+1);
LAM = beta*LAM(+1)*(RK(+1) + (1-delta));
LAM = 1/C;
W = sigmaL/(sigmaL-1)*omega*L^(nu)*1/LAM;
Y = A*L^(alpha)*K(-1)^(1-alpha);
RK = (1-alpha)*MC*A*L^(alpha)*K(-1)^(-alpha);
W = alpha*MC*A*L^(alpha-1)*K(-1)^(1-alpha);
1 - phiP*(PI-1)*PI + beta*phiP*LAM(+1)/LAM*(PI(+1)-1)*Y(+1)/Y*PI(+1) - (1-MC)*Phi = 0;
B = R(-1)*B(-1)/PI + G - TAX;
TAX/TAXBAR =  (B/Bss)^tau;
R/Rss = (PI)^(jotaPI)*(Y/Yss)^(jotaY)*U;
K = (1-delta)*K(-1) + I;  
Y = C + I + G + phiP/2*(PI-1)^2*Y;
RR = R/PI(+1);
A = ((Ass)^(1-rhoA) )*( A(-1)^rhoA )*exp(eps_A);
U = ((Uss)^(1-rhoU) )*( U(-1)^rhoU )*exp(eps_U);
G = ((Gss)^(1-rhoG) )*( G(-1)^rhoG )*exp(eps_G);
end;


initval;
UTIL = log(Css) -omega/(1+nu)*Lss^(1+nu); 
B = Bss;
PI = 1;
A = Ass;
U = Uss;
G = Gss;
MC = (Phi-1)/Phi;
TAX = TAXss;
R = Rss;
W = Wss; 
L = Lss;
K = Kss;
Y = Yss;
C = Css;
LAM = LAMss;
RK = RKss;
I = Iss;
RR = Rss;
end;

steady;


shocks;
var eps_A = sigmaA;
var eps_U = sigmaU;
var eps_G = sigmaG;
end;

stoch_simul(periods=0,irf=20,order=1);
2

See

3

so if i understand that right, it is no mistake, that my nominal interest rate drops. But how can that be: “For example, in the standard New Keynesian model the nominal interest rate can move in either direction after a contractionary monetary policy shock. The only thing that is guaranteed is that the real interest rate increases.” ??

4

All I am saying is that it could be a feature and not a bug. I did not check your model.

The mechanism is the following: Assume the initial monetary policy shock increases the nominal and thus the real interest rate. The central bank then reacts to lower output and inflation endogenously by lowering the nominal interest rate. If the response is strong enough, it overcompensates the initial increase due to the shock. The only thing you know is that the real interest rate increases, so that the shock is still contractionary, although the nominal interest rate goes down. This is one of the reasons why you cannot look at interest rates to determine whether monetary policy is expansionary.

1 Like
5

Okay! I think I understand you. Many thanks for our fast answer!!

6

If I understand, in the model, after a contractionary monetary policy shock, an increase in the nominal interest rate is not guaranteed but an increase in the real interest rate is always guaranteed, right? Thus, the real interest rate in the model could be close to zero but it is never negative following a contractionary monetary policy shock, right?

Or, is it possible that after a contractionary monetary policy shock, some friction in the model could make an increase in real interest rate also not guaranteed such that the real interest rate falls, and price and output increases? Is that possible?

7

Yes, frictions in the model and particularly the presence of capital can alter that result.

8

If I may ask, if we can get a situation where contractionary monetary policy shock causes real interest rate to fall, and inflation and output to increase in an NK DSGE model, then why do people call it a puzzle then since it is a possible equilibrium in the model?

9

In the simple model it is indeed a puzzle because it could not happen. For more complicated models, see On the mechanics of New-Keynesian models