Hi all!
I am working on a real business cycle model. I am very new to Dynare programme. When I run the model, it says: There are 7 eigenvalue(s) larger than 1 in modulus for 10 forward-looking variable(s)
The rank condition ISN’T verified!
Error using print_info (line 45) Blanchard Kahn conditions are not satisfied: indeterminacy.
I have tried different timing for predetermined variables but still couldn’t get any result.
Does someone have an idea how to overcome this problem?
I appreciate any help that you can provide.
var
chat // consumption deviation from the trend
ihat // investment deviation from the trend
nhat // labor supply deviation from the trend
qhat // price of capital deviation from the trend
Rhat // deposit rate deviation from the trend
Rkhat // return to capital deviation from the trend
khat // capital stock deviations from trend
zhat // productivity deviations from trend
what // real wage deviations from trend
hhat // labor demand deviations from trend
xihat // financal condition deviations from trend
vahat // bank net worth (after the shock) deviations from trend
vbhat // bank net worth (before the shock) deviations from trend
nthat // the marginal benefit of having one more unit of net worth deviation
vthat // the marginal gain to the bank of buying one more unit of firms' shares
shat // quantity of shares (owned by bank) deviations from trend
;
%////////////////////////////////////////////////
%// exogenous variables
%////////////////////////////////////////////////
varexo eps_z // Technology shock
eps_xi // Financial shock
;
%////////////////////////////////////////////////
%// parameters
%////////////////////////////////////////////////
parameters betta // quarterly discount factor
upsilon // relative utility weight of leisure
alppha // share of capital in output
phi // capital adjustment cost parameter
delta // depreciation rate of capital
lambda // the fraction of assets that can be diverted
epsilon // proportional transfer to the entering bankers
theta // survivor probability of the bankers
siggma // standard deviation
rho_z // persistence of TFP process
sigma_z // standard deviation of productivity shock
rho_xi // persistence of net worth process
sigma_xi // standard deviation of net worth shock
covariance_z_xi
;
%////////////////////////////////////////////////
%// set parameter values
%////////////////////////////////////////////////
betta=0.9942;
upsilon=1.7167;
alppha=0.36;
phi=3.6;
delta=0.025;
lambda=0.1548;
epsilon=0.001;
theta=0.9685;
siggma=1;
rho_z=0.9315;
sigma_z=0.006424;
rho_xi=0.3744;
sigma_xi=0.0512;
covariance_z_xi=0;
%////////////////////////////////////////////////
%// model
%////////////////////////////////////////////////
%//The first 16 equations are obtained from the competitive equilibrium in Appendix C
model(linear);
#zstar=1;
#xistar=1;
#qstar=1;
#Rstar=1/betta-1;
#Rkstar=1/betta-1;
#nstar=((1-alppha)/theta*((1/betta-1+delta)/alppha)^(alppha/(alppha-1)))/((theta+1-alppha)/theta* ((1/betta-1+delta)/alppha)^(alppha/(alppha-1))-delta*((1/betta-1+delta)/alppha)^(1/(alppha-1)));
#kstar=((1/betta-1+delta)/alppha)^(1/(alppha-1))*nstar;
#cstar =(kstar/nstar)^alppha*(1-alppha)/theta*(1-nstar);
#ystar=(kstar/nstar)^alppha*nstar;
#istar=delta*kstar;
#sstar=kstar;
#ntstar=(1-theta)/(1+betta*theta);
#vastar =qstar*sstar*(lambda/ntstar);
#vbstar=vastar;
#vtstar=0;
//1
1/(1-nstar)*nstar*nhat+siggma*chat=what;
//2
siggma*chat(+1)-siggma*chat=Rhat(+1);
//3
Rkhat(+1)*Rkstar=(zhat(+1)+(1-alppha)*khat+(1-alppha)*nhat(+1))*(nstar/kstar)^(1-alppha)+(qhat(+1)-qhat)*qstar;
//4
what=zhat+alppha*khat(-1)-alppha*hhat;
//5
vahat*vastar=xihat+vbhat*vbstar;
//6
qhat+shat=nthat-vthat*vtstar/(lambda-vtstar)+vahat;
//7
nthat*ntstar=(1-theta)*betta*Rhat(+1)*Rstar+betta*theta*((vahat(+1)-vahat)+nthat(+1));
//8
vthat*vtstar=(1-theta)*betta*(Rkhat(+1)*Rkstar-Rhat(+1)*Rstar)+betta*theta*(qhat(+1)-qhat+shat(+1)-shat+vahat(+1));
//9
vbhat(+1)*vbstar=theta*(Rkhat(+1)*Rkstar-Rhat(+1)*Rstar+nthat+vthat*vtstar/(lambda-vtstar)+Rhat(+1)*Rstar)+epsilon*vbhat;
//10
shat=khat;
//11
khat=khat(-1)-delta*khat(-1)-ihat*(istar/kstar)+(-phi*delta*(ihat-khat(-1)))*istar/kstar;
//12
qhat*qstar=(phi*(ihat-khat(-1)))*(istar/kstar);
//13
hhat=nhat;
//14
chat*cstar/ystar+ihat*istar/ystar=zhat+alppha*khat(-1)+(1-alppha)*hhat;
//15
zhat=rho_z*zhat(-1)+eps_z;
//16
xihat=rho_xi*xihat(-1)+eps_xi;
end;
%////////////////////////////////////////////////
%// steady state models
%////////////////////////////////////////////////
steady_state_model;
chat=0;
ihat=0;
nhat=0;
qhat=0;
Rhat=0;
Rkhat=0;
khat=0;
zhat=0;
what=0;
hhat=0;
xihat=0;
vahat=0;
vbhat=0;
nthat=0;
vthat=0;
shat=0;
end;
shocks;
var eps_xi; stderr 0.01;
var eps_z; stderr 0.01;
var eps_z,eps_xi=covariance_z_xi ;
end;
resid(1);
steady;
check;
stoch_simul(hp_filter=1600,irf=20);