//---------------------------------------------------------------------
// 1. Variable declaration endogenes
//---------------------------------------------------------------------

var 
dr          
dw          
cr          
cw          
TR          
TW          
LR          
LW          
p           
kap         
epsil       
bigomeg    
hr          
hw          
W          
R           
A           
k           
lambd       
y           
Z           
;



//---------------------------------------------------------------------
// 2. Parameter declaration and calibration
//---------------------------------------------------------------------

parameters
nu
tau
bet
delt
sigm
alf
omeg
gam
x
n
ph
varepsil
rh
ch
psi
;


%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% Calibration 
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

nu=0.4;
bet=0.96;
delt=0.1;
sigm=0.25;
alf=0.667;
omeg=0.977;
gam=0.9;
x=0.01;
n=0.01;
ph=0.75;
varepsil=0.55;
rh=0.9;
ch=(1/varepsil)^(1-nu);
tau=(1-nu)^(nu-1)*nu^(-nu);
psi=(1-omeg)/(1+n-gam);


//---------------------------------------------------------------------
// 3. Model 
//---------------------------------------------------------------------

model;  

%equation 1
p*dr=  ch*epsil*kap*hr+ch*epsil*kap*A*R*lambd;


%equation 2
epsil(+1)*kap(+1)-epsil*kap*epsil(+1)*kap(+1)=  bet^(sigm)*gam*p^(sigm-1)*p(+1)^(1-sigm)*R(+1)^(sigm-1)*epsil*kap;


% equation 3
R(+1)*hr =  varepsil*psi*R(+1)*W+gam*hr(+1)+x*gam*hr(+1);


% equation 4
p*dw    =  kap*(hw-A*R*(lambd-1));


%equation 5

kap(+1)-kap*kap(+1)=  bet^(sigm)*p^(sigm-1)*p(+1)^(1-sigm)*R(+1)^(sigm-1)*kap*bigomeg(+1)^(sigm-1);

%equation 6

bigomeg(+1)                       =  omeg+ch*(1-omeg)*epsil(+1)^(1/(1-sigm));


%equation 7

hw*R(+1)*bigomeg(+1)+ch*hr(+1)*epsil(+1)^(1/(1-sigm))*(x*omeg/psi-x/psi+omeg/psi-1/psi)= R(+1)*bigomeg(+1)*W+x*omeg*hw(+1)+omeg*hw(+1);


%equation 8

(1-nu)*p*dr =  varepsil*ch*psi*W*LR;


% equation 9

ch*dr                             =  nu*p*dr;

% equation 10

(1-nu)*p*dw                       =  W*LW;


% equation 11

cw                               =  nu*p*dw;

% equation 12
p                                =  tau*W^(1-nu);


% equation 13

lambd(+1)+omeg*hr*epsil*kap=(1-omeg)*(1+n)*(1+x)*A(+1)+varepsil*psi*omeg*W+omeg*A*R*(1-epsil*kap)*lambd;


% equation 14
y+k=cr+cw+k(+1)+n*k(+1)+x*k(+1)+n*x*k(+1)+delt*k;

% equation 15

alf*y=varepsil*psi*W*TR+W*TW;

% equation 16

(1-alf)*y/k=R+delt-1;


% equation 17

y=Z*(varepsil*psi*TR+TW)^(alf)*k^(1-alf);


% equation 18

k=A;


% equation 19

TR                            =  1-LR;

% equation 20
TW                            =  1-LW;

% equation 21

Z(+1)                         =   Z^ph;
end;

//---------------------------------------------------------------------
// 4. Initial values and steady state
//---------------------------------------------------------------------

initval;
p       =        1.898;
W       =        0.948;
LR      =        0.243;
LW      =        0.243;
TW      =        0.377;
TR      =        0.756;
hr      =        0.745;
hw      =        10.296;
R       =        1.064;
k       =        1.165;
A       =        11.347;
lambd   =        0.152;
epsil   =        1.732;
kap     =        0.086;
bigomeg   =      1.045;
y       =        0.576;    
dr      =        0.103;     
dw      =        0.517;
cr      =        0.054;
cw      =        0.393;
Z      =        1.000;    
end;


resid;

%options_.noprint = 1;

steady;  

check;