//In the Name of Allah
var
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Variables of Consumer Equations:
//First Equation Variables
cc${\hat{c}^{c}}$ rd$\hat{r}^{d}$ pi$\hat{\pi}$ lac$\hat{\lambda}^{c}$
//Second Equation Variables
n$\hat{n}$ w$\hat{w}$
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Variables of Entrepreneur Sector
//Thitrd Equation Variables
ce$\hat{c}^{e}$ lae$\hat{\lambda}^{e}$
//Fourth Equation Variables
gae$\hat{\gamma}^{e}$ rb$\hat{r}^{b}$
//Fifth Equation Variables
lv$\hat{lv}$ q$\hat{q}$ rk$\hat{r}^{k}$ b$\hat{b}$
//Sixth Equation Variables
ye$\hat{y}^{e}$ xi$\hat{xi}$
//7th Equation Variables
ke$\hat{k}^{e}$ kg$\hat{k}^{g}$ a$\hat{a}$
//8th Equation Variables
or$\hat{or}$
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Banking Sector
//15th Equation Variables
rrb$\hat{rrb}$ rrs$\hat{rrs}$
kb$\hat{k}^{b}$
//18th Equation Variable
mkb$\hat{mk}^{b}$
mkd$\hat{mk}^{d}$
//Bank balance Sheet
d$\hat{d}$
jr$\hat{j}^{r}$
//Bank's Profit
jb$\hat{jb}$
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Government Sector
//21th Equation Variables
g$\hat{g}$
//22th Equation Variables
ig$\hat{ig}$
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Capital Producer Sector
//24th Equation Variables
psi$\hat{\psi}$
//26th Equation Variables
ip$\hat{ip}$
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Monetary Sector
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//28th Equation Variables: Market Clearing Condition
y$\hat{y}$
o1
o2
yobs${y\_obs}$
ipobs${ip\_obs}$
igobs${ig\_obs}$;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Macroprudential policy variables
//epslv$\hat{\epsilon}^{lv}$;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
varexo
varlv$\hat{\epsilon}^{lv}$
vara$\varepsilon^{a}$
varmkb$\varepsilon^{mkb}$
varmkd$\varepsilon^{mkd}$
//varkb$\varepsilon^{k_b}$
varg$\varepsilon^{g}$
varor$\varepsilon^{or}$
varig$\varepsilon^{ig}$
varpsi$\varepsilon^{\psi}$
varrrs$\varepsilon^{rrs}$;
parameters
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Parameters of Consumer Equations:
//First Equation Parameters
bbc${\beta^{c}}$,
csig${\sigma_{c}}^{c}$ (long_name='Consumer Elasticity of Substituition'),
//Second Equation Parameters
//nsig${\sigma_{c}}^{n}$ (long_name='Frisch Elasticity of Labor Supply'),
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Parameters of Entrepreneur Sector
//3th Equation Parameters
csige${\sigma_{e}}^{c}$ (long_name='Entrepreneur Elasticity of Substituition'),
//4th Equation Parameters
bbe$\beta^{e}$,
//6th Equation Parameters
ddk$\delta_{k}$ (long_name='Depreciation rate'),
aa$\alpha$ (long_name='Share of Capital in Production'),
piss$\bar{\pi}$(long_name='steady state of inflation'),
ind_p$ind_p$(long_name='sensivity to inflation'),
ind_d$ind_d$(long_name='sensivity to inflation'),
ind_b$ind_b$(long_name='sensivity to inflation'),
//8th Equation Parameters
teta$\theta$(long_name='share of public capital in production'),
//9th Equation Parameters
//10th Equation Parameters
rhoa$\rho^{a}$(long_name='Coefficient of Productivity process'),
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Parameters of retail Sector
epsy${\epsilon}^{y}$(long_name='Elasticity of Substitution'),
kap${\kappa^{p}}$(long_name='cost of adjusting price for retail sector'),
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Parameters of Banking Sector
//15th Equation Parameters
kad${\kappa^{d}}$(long_name='cost of adjusting deposit interest rate'),
//16th Equation Parameters
kab${\kappa^{l}}$(long_name='cost of adjusting borrowing interest rate'),
//18th Equation Parameters
kak${\kappa^{k}}$(long_name='Adjustment Coeeficient in Wholesale Branch cost Function'),
car$car$(long_name='Banking Capital ratio over assets (Basel II)'),
etab${\eta}^{b}$
etad${\eta}^{d}$
ba$\bar{a}$,
blv$\bar{lv}$,
bpsi$\bar{psi}$,
bmkd$\bar{mkd}$,
bmkb$\bar{mkb}$,
bor$\bar{or}$,
bg$\bar{g}$,
bip$\bar{ip}$,
big$\bar{ig}$,
//20th Equation Parameters
rhode$\rho^{de}$,
//21th Equation Parameters
rholo$\rho^{lo}$,
ddb$\delta_{b}$ (long_name='Depreciation of Bank Capital'),
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Parameters of Government Sector
//23th Equation Parameters
rhog$\rho^{g}$,
//24th Equation Parameters
ddg$\delta_{g}$ (long_name='Depreciation of Public Investment'),
rhoig$\rho^{ig}$,
rhoio$\rho^{io}$,
//25th Equation Parameters
rhoo$\rho^{or}$,
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Parameters of Producing capital Sector
//27th Equation Parameters
//28th Equation Parameters
kai$\kappa_{I}$(long_name='cost of adjusting capital'),
//29th Equation Parameters
rhop$\rho^{\psi}$,
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Parameters of Monetary Sector
//31th Equation Parameters
rhoy$\rho^{y}$,
rhorrs$\rho^{rrs}$,
rhopi$\rho^{\pi}$,
//31th Equation Parameters
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//parameters of Lv Equation
rholv$\rho^{lv}$;
bbc=0.995;//R1; (shah hosseini and bahrami (0.979)) (Komeijaniand Tavakolian = 0.987)
csig=1.25;//R1 & R8 (Komeijani and Tavakolian=1.30)
//nsig=2.17;//R10
csige=1;//Gerali et. al (2009)
bbe=0.965;//daliri & mehregan (Brozaza-Brezina, Kolasa and Makarski (2010),Gerali et al (2009) (=0.975)) (=0.9085) (0.9748733913) (=0.978465)
ddk=0.016;//R1 & R-8 (shah hosseini and bahrami (0.031)) (Eskandari, pedram and bostani (1397)=0.027) (hosein tavakolian komijani=0.0426)
ddg=0.03;//sayadmanesh and teimori//tavakolian and komeijani 1391 (R-9=0.0728)
aa=0.47;//tavakolian and komeijani (Dargahi and Hadian (1395) =0.412) (Eskandari, pedram and bostani (1397)=0.47)(0.4278=tavak and komi)
//nu=0.10;//assumption
rholv=0.75;//Gerali et al (2009)
teta=0.0945;//Komeijani and Tavakolian(=0.0945)
rhoa=0.72;//R-2
etab=16.15;
etad=46.54;
ba=1;
blv=0.7026;
bpsi=0.18225;
bmkd=1.02195871;//bmkd=etad/(etad-1)
bmkb=1.0660066;//bmkb=etab/(etab-1)
bor=0.07;
bg=0.14;
bip=0.21;
big=0.1;
piss=1.04;//Teimour Rahmani (tarh)(=0.18/4=0.045)
ind_p=0.55;
ind_d=.45;
ind_b=0.35;
ddb=.01;
epsy=10;
kap=100;//gerali et al
kab=3;//Gerali et al (2009) (Farsi: Hosseini and Molabahrami)
kad=4;//Gerali et al (2009)(Farsi: Hosseini and Molabahrami)
kai=0.5;//R.15
rholo=0.80;//Gerali etal (2009)
rhode=0.80;//Gerali etal (2009)
kak=0.5;//Gerali, et. al (2009)
car=0.08;//Central Bank determine CAR ratio (Teimour rahmani (tarh)) (Mohebi, Shahrestani and Hojabri (1396))
rhog=0.44;//R.22
rhoo=0.72;//R-2,14 (=.55) (.72=R.11)
rhoig=0.65;
rhoio=0.30;
rhop=0.8;//Amiri (1394)
rhoy=0.46;//Shah hosseini & Bahrami
rhorrs=0.80320;//Shah hosseini & Bahrami
rhopi=1.4;//Shah hosseini & Bahrami (daliri & Mehregan=0.60)
model;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Consumer Sector
//Equation 1:Euler Equation
exp(cc) ^ (-csig) = exp(lac) ;
//Equation 2:Supply of Labor
//ssi*exp(n) ^ nsig = exp(w) * exp(lac) ;
exp(n)=0.333;
//Equation 3: Foc Deposit
exp(lac) = bbc * (1 + exp(rd)) * exp(lac(+1)) / exp(pi(+1)) ;
//Equation 4: Consumer Budget Constraint
//exp(cc) + exp(d) = exp(w) * exp(n) + (1+exp(rd(-1))) * exp(d(-1)) / exp(pi) + exp(jr);
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Entrepreneur Sector
//Equation 4:Entrepreneur Consumption
exp(ce) ^ (-csige) = exp(lae) ;
//Equation 5:Entrepreneur Loan Demand
exp(lae) = exp(gae) * (1 + exp(rb)) + bbe * exp(lae(+1)) * ((1 + exp(rb)) / (exp(pi(+1)))) ;
//Equation 6:Entrepreneur Capital Demand
exp(lae) * exp(q) = exp(lv) * exp (pi(+1)) * exp(q(+1)) * exp(gae) * (1-ddk) + bbe * exp(lae(+1)) * (exp(q(+1)) * (1-ddk) + exp(rk(+1))) ;
//Equation 7:Entrepreneur Labor Demand
exp(w) * exp(n) * exp(xi) = (1-aa) * exp(ye) ;
//Equation 8:Production function of Entrepreneur
exp(ye) = exp(a) * (exp(ke(-1)) ^ aa) * (exp(n) ^ (1-aa)) * (exp(kg(-1)) ^ teta) ;
//Equation 9: Macroprudential Policy (process defined for evolution of LTV)
exp(lv) / blv = ((exp(lv(-1)) / blv) ^ rholv) * exp(varlv) ;
//Equation 10: AR(1) Process for TFP Shock
exp(a) / ba = ((exp(a(-1)) / ba) ^ rhoa) * exp(vara) ;
//Equation 11: Borrowing Constraint of firm
exp(b) * (1 + exp(rb)) = exp(lv) * exp(q(+1)) * exp(pi(+1)) * exp(ke) * (1-ddk);
//Equation 12: Entreprenuer Budget Constraint
exp(ce) + exp(w) * exp(n) + (((1 + exp(rb(-1))) / exp(pi)) * exp(b(-1))) + exp(q) * exp(ke) = (exp(ye) / exp(xi)) + exp(b) + exp(q) * (1-ddk) * exp(ke(-1));
//Equation 13: Rent Of Capital
exp(rk) = aa * exp(ye) /(exp(ke(-1)) *exp(xi));
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Retail Sector
//Equation 14:New Keynsian Philips Curve
0 = 1 - epsy + epsy / exp(xi) - kap * (exp(pi)-(exp(pi(-1)) ^ ind_p) * (piss ^ (1-ind_p))) * exp(pi) + bbc * (exp(lac(+1)) / exp(lac)) * kap * (exp(pi(+1))-(exp(pi) ^ ind_p * piss ^(1-ind_p))) * exp(pi(+1)) * (exp(y(+1)) / exp(y));
//Equation 15: Retailor Sector Profit
exp(jr) = exp(y)*(1 - (1/exp(xi)) - (kap/2) * (exp(pi) - ( exp(pi(-1)) ^ ind_p * piss ^ (1-ind_p) ))^2 ) ;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Banking Sector Equations:
//Equation 16:FOC of Wholasale Branch
exp(rrb) = -kak * ((exp(kb) / exp(b)) - car) * (exp(kb) / exp(b)) ^ 2 + exp(rrs) ;
//Equation 17: Loan Supply by Bank
1- (exp(mkb)/(exp(mkb)-1)) + (exp(mkb)/(exp(mkb)-1)) * (exp(rrb) / exp(rb))- kab * (((exp(rb)) / (exp(rb(-1)))) - ( exp(rb(-1)) / exp(o2(-1)) )^ind_b) * (exp(rb)/exp(rb(-1)))
+ bbc * kab * (exp(lac(+1)) / exp(lac)) * (((exp(rb(+1))) / (exp(rb))) -( exp(rb)/exp(rb(-1)))^ind_b ) * (((exp(rb(+1))) / (exp(rb))) ^ 2) * (exp(b(+1)) / exp(b)) = 0 ;
//Equation 18: Demand Deposit by Bank
-1 + (exp(mkd)/(exp(mkd)-1)) - (exp(mkd)/(exp(mkd)-1)) * (exp(rrs) / exp(rd)) - kad * ((exp(rd) / exp(rd(-1))) -(exp(rd(-1)) / exp(o1(-1)) )^ind_d) * (exp(rd) / exp(rd(-1)))
+ bbc * kad * (exp(lac(+1)) / exp(lac)) * (((exp(rd(+1))) / (exp(rd))) - ( exp(rd)/exp(rd(-1)))^ind_d ) *(((exp(rd(+1))) /(exp(rd)))^2) * (exp(d(+1)) / exp(d)) = 0 ;
//Equation 19: Ar(1) Process for elasticity of substitution between deposit interest rate
exp(mkd) / bmkd = ((exp(mkd(-1))/bmkd) ^ rhode) * exp(varmkd);
//Equation 20: Ar(1) Process for elasticity of substitution between loan interest rate
exp(mkb) / bmkb = ((exp(mkb(-1)) / bmkb) ^rholo) * exp(varmkb);
//Equation 21: Bank Balance Shhet Equation
exp(b) = exp(d) + exp(kb);
//Equation 22: KB Evolution
exp(kb) * exp(pi) = (1-ddb) * exp(kb(-1)) + exp(jb(-1)) ;
//Equation 23: Banks Profit
exp(jb) = + exp(rb) * exp(b)
- exp(rd) * exp(d)
- kad/2 * ( (exp(rd)/exp(rd(-1))-1)^2) * exp(rd) *exp(d)
- kab/2 * ( (exp(rb)/exp(rb(-1))-1)^2) * exp(rb)*exp(b)
- kab/2 * ( (exp(kb) / exp(b) - car ) ^2) * exp(kb);
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Government Sector Equations:
//Equation 24: Government Expenditure Process
exp(g) / (bg*exp(steady_state(ye))) =(exp(g(-1))/(bg*exp(steady_state(ye)))) ^ rhog * exp(varg);
//Equation 25: Public Investment Process
exp(kg)=(1-ddg) * exp(kg(-1))+ exp(ig);//coeefiicient of ig???
//Equation 26: oil revenue process
(exp(ig)/(big*exp(steady_state(y)))) = (exp(ig(-1))/(big*exp(steady_state(y)))) ^ rhoig * (exp(or(-1))/(bor*exp(steady_state(y)))) ^ (rhoio) * exp(varig);
//Equation 27: oil revenue process
exp(or) / (bor*exp(steady_state(ye))) = ((exp(or(-1)) / (bor*exp(steady_state(ye)))) ^ rhoo) * exp(varor);
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Capital Producer Equations
//Equation 28: Q-Tobin Process
1 = exp(q) * (1 - kai /2 * (exp(ip) * exp(psi) / exp(ip(-1)) -1) ^ 2 - kai*((exp(ip)* exp(psi) / exp(ip(-1)) - 1) *((exp(ip) * exp(psi) / exp(ip(-1)))))) + bbc * kai * ((exp(lae(+1)) / exp(lae)) * exp(q(+1)) * ((exp(ip(+1)) * exp(psi(+1)) / exp(ip) -1)) * exp(psi(+1)) * (exp(ip(+1))/exp(ip)) ^ 2) ;
//Equation 29: Shock to Marginal Efficiency of Investment
exp(psi) /bpsi=(exp(psi(-1)) / bpsi) ^ rhop * exp(varpsi);
//Equation 30: Law Of Motion of Capital
exp(ke)=(1-ddk) * exp(ke(-1)) + (1 - (kai/2) * (exp(ip) *exp(psi)/ exp(ip(-1))-1) ^ 2) * exp(ip);
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Equation 31: Monetary Sector Equations:
(1+exp(rrs)) = (1+exp(steady_state (rrs)))^(1 - rhorrs ) * (1+exp(rrs(-1)))^rhorrs * (( exp(pi) / piss ) ^rhopi *
(exp(y)/exp(y(-1)))^rhoy ) ^ ( 1 - rhorrs ) * (1+varrrs) ;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
//Equation 32: entreprenuer and retailer Output relation
exp(y) = exp(ye);
//Equation 33: Market Clearing Condition
exp(y) = exp(cc) + exp(ce) + exp(g) + exp(ip) + exp(ig);
o1=rd(-1);
o2=rb(-1);
yobs = y - steady_state (y);
ipobs = ip - steady_state (ip);
igobs = ig - steady_state (ig);
end;
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
steady;
shocks;
var varlv;
stderr 1;
var vara;
stderr 1;
var varmkb;
stderr 1;
var varmkd;
stderr 1;
//var varkb;
//stderr 0.01;
var varg;
stderr 1;
var varor;
stderr 10;//STDERROR=0.15 (R.13)
var varig;
stderr 1;
//var varpsi;
//stderr 0.01;
var varrrs;
stderr 1;//STDERROR=0.14 (R.13)
end;
//model_diagnostics;
varobs yobs ipobs igobs;
check(qz_zero_threshold=1e-20);
estimated_params_init(use_calibration);
end;
estimated_params;
//bbc, beta_pdf, 0.987, 0.02; //Consumer Preference (R.2)
//bbc, beta_pdf, 0.987, 0.01; //Consumer Preference (R.2)
csig, gamma_pdf, 1.571, 0.01; //Consumer Elasticity of Substitution (R.2)
//nsig, gamma_pdf, 2.17, 0.01; //labor elasticity of subsitution (R.2)
aa, beta_pdf, 0.47, 0.01; //capital Share in production (R.8)
//ddk, beta_pdf, 0.016, 0.01;// Depreciation rate (R.9)
ddg, beta_pdf, 0.03, 0.01;// Depreciation rate (R.9)
rhoa,beta_pdf, 0.76, 0.01; //(R.12) (is it between 0 and 1????)
teta, beta_pdf, 0.0945, 0.01;//Elasticity of Subs. between private and Government capital (R.8)
//nu, normal_pdf, 0.10, 0.01;// Loan to value ratio (R.9: Defined a gamma distribution)
rhoo, beta_pdf, 0.72, 0.01; //Autoregressive of oil revenue coeef (R.9)
//rhog, beta_pdf, 0.44, 0.01; //(R.12)
rhopi, gamma_pdf, 1.40, 0.01; //(R.9) (Is itBetween 0 and 1???)
//rhorrs, beta_pdf, 0.80320, 0.01; //Assumption (Is itBetween 0 and 1???)
//rholo,beta_pdf, 0.80, 0.01; //Gerali etal (2009)
//rhode,beta_pdf,0.80,0.01;//Gerali etal (2009)
//rhoko,beta_pdf,0.68,0.01;
stderr varlv, inv_gamma_pdf, 0.01, inf; //Standard Error of oil revenue (R.8)
stderr vara, inv_gamma_pdf, 0.01, inf; //Standard Error of oil revenue (R.8)
stderr varmkb, inv_gamma_pdf, 0.01, inf; //Standard Error of oil revenue (R.8)
stderr varmkd, inv_gamma_pdf, 0.01, inf; //Standard Error of oil revenue (R.8)
//stderr varkb, inv_gamma_pdf, 0.05, inf; //Standard Error of oil revenue (R.8)
stderr varg, inv_gamma_pdf, 0.01, inf; //Standard Error of oil revenue (R.8)
stderr varig, inv_gamma_pdf, 0.01, inf; //Standard Error of oil revenue (R.8)
stderr varor, inv_gamma_pdf, 0.01, inf; //Standard Error of oil revenue (R.8)
//stderr yobs, inv_gamma_pdf, 0.01, inf;
end;
estimated_params_init(use_calibration);
end;
//dynare_sensitivity;
//identification;
//identification(parameter_set=posterior_mode);
//resid;
//identification (advanced=1, max_dim_cova_group=3, prior_mc=250, lik_init=3) ;
estimation(tex,datafile=mydata5,first_obs=1,mode_compute=6,diffuse_filter,mode_check,mh_replic=100,mh_jscale=0.35,mh_nblocks=3,irf=40,prior_trunc=0) y ip ig;
//stoch_simul(tex,hp_filter=1600,order=1,periods=10000,irf=40,qz_zero_threshold);
stoch_simul(irf=40,order=1,pruning,tex) ke ip y b pi;