var c         //consumption
    mc        //real marginal costs
    i         //Nominal Interest rate
    rd        //Deposit interest rate
    rl        //Loan granting rate
    PI        //Inflation
    rk        //rental rate of capital
    x         //investment
    w         //real wage 
    A         //AR(1) technology process
    y         //aggregate output
    n         //aggregate labor 
    k         //capital
    m         //monetary base
    mb        //nominal money growth
    l         //loan  
    or        //oil revenues
    tao       //Legal reserve rate 
    g         //government expenditure
    fr        //foreign reserves (net foreign assets) of the central bank
    ndf       //national development fund
    dc        //domestic credit
    d         //deposit
    mh
    mb1
   gy_obs 
   gor_obs 
   gg_obs
   gc_obs
   gk_obs;
     
varexo epsA epstao epsor epsg nu epsmb1;

predetermined_variables k;

parameters betta        //discount factor
           psin         //
           psim         //
           delta1        //depreciation rate
           alppha       //capital share
           rhoA         //autocorrelation technology shocks
           theta        //elasticity of substitution between goods varieties
           phi          //degree of nominal price rigidity
           Lambda
           alphab
           PIbar
           rhomb
           rhog
           rhotao
           rhoor
           roa
           ybar
           mbbar
           LambdaPI
           Lambday
           omega
           phiPI
           phiy
           phimb1;
           
           
psin         =4.77;                     //bahrami and rafei (1393)
psim         =0.24;                     //bahrami and rafei (1393)
theta        =5.83;                     //bahrami and rafei (1393)
phi          =3.15;                     //bahrami and rafei (1393)
delta1       =0.04;                     
betta        =0.9622;                   //tavakolian (1394, spring)
alppha       =0.42;                     //tavakolian (1394, spring)
rhoA         =0.9;                      //tavakolian (1394, spring)    
rhoor        =0.2862;                   //tavakolian (1394, spring)
rhomb        =0.79;                     //tavakolian (1394, spring)
rhog         =0.8;                      //
Lambda       =0.5;
PIbar        =1.15;
rhotao       =0.99;                     //parvin, ebrahimi and ahmadian (1393)                
alphab       =0.92;                     //parvin, shakeri and ahmadian (1393)
LambdaPI     =-1.07;                    //tavakolian (1394, spring)
Lambday      =-2.35;                    //tavakolian (1394, spring)
omega        =0.8;                      //tavakolian (1394, spring)
roa          =0.12;
mbbar        =PIbar;           
phiPI        =0.147;                    //parvin, ebrahimi and ahmadian (1393) 
phiy         =1.051;                    //parvin, ebrahimi and ahmadian (1393) 
phimb1       =0.694;                    //parvin, ebrahimi and ahmadian (1393) 

model; 

//1. Labor supply
w=psin*c;
//2.Demand for real money balance
c*(psim/mh)=i/(1+i);
//3. Euler equation
betta*(1+i)/PI(+1)=c(+1)/c;
//4.Fisher equation
(1+i)/PI(+1)=rk(+1)+(1-delta1);
//5. 
(1+rd)/PI(+1)=rk(+1)+(1-delta1);
//6.Law of motion for capital
k(+1)=x+(1-delta1)*k;
//7.production function
y=A*(n^(1-alppha))*(k^alppha);
//8.marginal cost
mc=(1/A)*(w/(1-alppha))^(1-alppha)*((rk*(1+Lambda))/alppha)^alppha;
//9.labour to Capital Services Input ratio
w/rk=((1-alppha)*(1+Lambda)*k)/(alppha*n);
//10.Phillips curve
(1-theta)*y-phi*((PI/PIbar)-1)*y+betta*phi*(c/c(+1))*((PI(+1)/PIbar)-1)*(PI(+1)/PIbar)*y(+1)+theta*mc*y=0; 
//11.loan to firm
l=(1+Lambda)*rk*k+w*n;
//12.Bank Balance Sheet
l=(1-Lambda+roa)*(mb1+d);
//13
mb1=(PI^phiPI)*(y^phiy)*(mb1(-1)^phimb1)*exp(epsmb1);
//14.Bank profit margin
(1+rd)=(1-Lambda+roa)*(alphab*(1+rl)-tao*(1-alphab));
//15.Monetary Base (Central Bank Balance Sheet)
m=dc+fr;
//16.Foreign reserves (net foreign assets) of the central bank
fr=(fr(-1)/PI)+omega*or;
//17.National Development Fund
ndf=(ndf(-1)/PI)+(1-omega)*or;
//18.Monetary policy reaction function
(mb/mbbar)=(mb(-1)/mbbar)^rhomb*((PI/PIbar)^LambdaPI*(y/ybar)^Lambday)^(1-rhomb)*exp(nu);

//19.nominal money growth
mb=(m/m(-1))*PI;
//20.Market clearing
y=c+x+g+(phi*y/2)*((PI/PIbar)-1);
//21
m=mh+d;

//exogenous processes
//22. Neutral technology
A=A(-1)^rhoA*exp(epsA); 
//23.Legal reserve rate
tao=tao(-1)^rhotao*exp(epstao);
//24.Oil revenues
or=or(-1)^rhoor*exp(epsor);
//25.government expenditure
g=g(-1)^rhog*exp(epsg);

gy_obs=y/y(-1);
gor_obs=or/or(-1); 
gg_obs=g/g(-1);
gc_obs=c/c(-1);
gk_obs=k/k(-1);
end;

shocks;
var epsA; 
stderr 0.01;
var epstao; 
stderr 0.01;
var epsor; 
stderr 0.01;
var epsg;
stderr 0.01;
var nu; 
stderr 0.01;
var epsmb1; 
stderr 0.01;
end;


//steady;
//stoch_simul(order=1,irf=40) y c x g m n k w l d PI i rk rl rd;

//resid(1);
//check;
//model_diagnostics;


// OBSERVABLE VARIABLES

varobs  gy_obs gg_obs gor_obs  gc_obs gk_obs;



estimated_params;
rhomb ,        beta_pdf,     0.5,      0.05;
rhoA,          beta_pdf,     0.9,      0.05;
phi,           gamma_pdf,    3.15,     0.05;
//theta,         gamma_pdf,    5.83,     0.05;  
betta,         beta_pdf,     0.9622,   0.01;
alppha,        beta_pdf,     0.42,     0.02;
rhog,          beta_pdf,     0.8,      0.1;       
psin,          gamma_pdf,    4.77,     0.05;
psim,          gamma_pdf,    0.24,     0.05;
rhoor,         beta_pdf,     0.8,      0.1;
Lambda,        beta_pdf,     0.5,      0.1;
//rhotao,        beta_pdf,     0.99,     0.01;                                 
//alphab,        beta_pdf,     0.92,     0.1;
//roa,           beta_pdf,     0.12,     0.1;
LambdaPI,      normal_pdf,  -1.07,     0.05;
//Lambday,       normal_pdf,  -2.35,     0.17;
//omega,         beta_pdf,     0.8,      0.05;
//phiPI,         normal_pdf,   0.147,    0.05;                    
//phiy,          normal_pdf,   1.051,    0.05;  
//phimb1,        beta_pdf,     0.694,    0.05;  
       
stderr epsA,       inv_gamma_pdf, 0.01, inf;
stderr epsor,      inv_gamma_pdf, 0.01, inf;
stderr epsg,       inv_gamma_pdf, 0.01, inf;
stderr nu,         inv_gamma_pdf, 0.01, inf;
//stderr epstao,     inv_gamma_pdf, 0.01, inf;
stderr epsmb1,     inv_gamma_pdf, 0.01, inf;

end;

// THE ESTIMATION BLOCK

estimation(datafile=data_bank, mh_jscale =0.3, mh_replic=5000, mh_nblocks=5, mode_compute=6,diffuse_filter, mode_check,order=1,bayesian_irf,irf=30) y c x g m n k w l mh d PI i rk rl rd;
//identification;

//stoch_simul(order=1,irf=40) y c x g m n k w l d PI i rk rl rd;