// Endogenous variables
var pi q qn interest a theta gamma sigma omega n wreal;
//Exogenous variables
varexo e ai z niu;
//parameters
parameters beta tau deltac deltan epsilon phi abar av rho miu rho0 kappa eta upsilon;

//Calibration
beta=0.96;
tau=0.25;
deltac=2;
deltan=1;
epsilon=10;
phi=0.4;
abar=1;
av=0.5;
rho=0.1;
miu=0.1;
rho0=0.1;
kappa=1.5;
eta=0.125;
upsilon=0.1;

//Equations of the model
model;
pi=beta*pi(+1)+(1-phi+phi*deltac+deltan)*tau*(1-beta*(1-tau))/((1-tau)*(phi+(1-phi)*epsilon))*(q-qn)+tau*phi*(1-miu*beta*(1-tau))/((1-tau)*(phi+(1-phi)*epsilon))*sigma;
q-qn=q(+1)-qn(+1)-1/deltac*(interest-pi(+1)+log(beta)+(rho-1)*gamma);
interest=-log(beta)+kappa*pi+eta*(q-qn);
qn=(phi+log(epsilon/(epsilon-1)))/(1-phi+phi*deltac+deltan)+(1+deltan)/(1-phi+phi*deltac+deltan)*a+phi*(2+deltan)/(1-phi+phi*deltac+deltan)*sigma;
a=(tau*abar+(1-tau)*av)*theta;
theta=rho0*theta(-1)+e;
gamma=rho*gamma(-1)+ai;
sigma=miu*sigma(-1)+z;
omega=upsilon*omega(-1)+niu;
n=1/phi*(q-a);
wreal=a+log(phi)+(phi-1)*n;
end;

//Initial values
initval;
pi=0.01;
q=0.01;
qn=0.01;
interest=0.01;
a=0.01;
theta=0.01;
gamma=0.01;
sigma=0.01;
omega=0.01;
n=0.01;
wreal=0.01;
end;

//Steady computation
steady;
resid;

//Check for B-K conditions
check;

//Shock
shocks;
var e;
stderr 0.05;
var ai;
stderr 0.05; 
var z;
stderr 0.05;
var niu;
stderr 0.05;
end;

//Bayesian Estimation
estimated_params;
abar,NORMAL_PDF,1,0.1;
av,NORMAL_PDF,0.2,0.1;
rho,BETA_PDF,0.5,0.2;
miu,BETA_PDF,0.5,0.2;
rho0,BETA_PDF,0.5,0.2;
kappa,GAMMA_PDF,1.5,0.2;
eta,GAMMA_PDF,0.125,0.05;
upsilon,BETA_PDF,0.5,0.2;
stderr e,INV_GAMMA_PDF,0.05,1;
stderr ai,INV_GAMMA_PDF,0.05,1;
stderr z,INV_GAMMA_PDF,0.05,1;
stderr niu,INV_GAMMA_PDF,0.05,1;
end;

varobs q n pi;

estimated_params_init(use_calibration);
end;

estimation(datafile=dataD,conf_sig=0.95,forecast=50,nobs=30,mode_check,mh_replic=1200,mh_jscale=0.2) pi q qn interest a theta gamma sigma omega n wreal;

//Stochastic simulation
stoch_simul(periods=100,irf=40,order=1);
figure(1);
subplot(1,1,1);
plot(oo_.endo_simul(1,:),'-b','Linewidth',1);