//CODE LUBIK SCHORFHEIDE(2007)

//14x endogenous variables(out of which 5 are observables and linked with xlsx
var e pi piw q r y yp yw z obs_e obs_pi obs_r obs_y obs_yw;


//5x exogenous variables
varexo eps_piw eps_q eps_r eps_yw eps_z;


//17x parameters
parameters alpha kappa psi_1 psi_2 psi_3 r_ss tau rho_r rho_q rho_piw rho_yw rho_z sigma_piw sigma_r sigma_q sigma_yw sigma_z;


//PRIORS OF PARAMETERS
alpha=0.2;
kappa=0.5;
psi_1=1.5;
psi_2=0.25;
psi_3=0.25;
tau=0.5;
r_ss=2.52;
rho_r=0.5;
rho_q=0.4;
rho_piw=0.8;
rho_yw=0.9;
rho_z=0.2;
sigma_piw=0.55;
sigma_q=1.5;
sigma_r=0.5;
sigma_yw=1.5;
sigma_z=1;


model(linear);

//COMPOSITES PARAMETERS (vérifier problèmes de dépendances entre beta et r_ss)

#beta=exp(-0.8119/400);


//1. IS CURVE
y=y(+1)-(tau+alpha*(2-alpha)*(1-tau))*(r-pi(+1))-rho_z*z-alpha*(tau+alpha*(2-alpha)*(1-tau))*(q)+alpha*(2-alpha)*((1-tau)/tau)*(yw);

//2. PHILLIPS CURVE
pi=beta*pi(+1)+alpha*beta*(q(+1))-alpha*(q)+(kappa/(tau+alpha*(2-alpha)*(1-tau)))*(y-yp);

//3. PPP
pi=(e-e(-1))+(1-alpha)*(q)+piw;

//4. MONETARY POLICY
r=rho_r*r(-1)+(1-rho_r)*(psi_1*pi+psi_2*y+psi_3*(e-e(-1)))+eps_r;

//5. TERMS OF TRADE MOVEMENT RULE
q=rho_q*(q(-1))+eps_q;

//6. WORLD OUTPUT
yw=rho_yw*yw(-1)+eps_yw;

//7. WOLRD INFLATION
piw=rho_piw*piw(-1)+eps_piw;

//8. GROWTH OF WORLD TECH INNOVATION
z=rho_z*z(-1)+eps_z;

//9. NATURAL GDP
yp=-alpha*(2-alpha)*((1-tau)/tau)*yw;

//10-16. OBSERVABLE VARIABLES (LINK XLSX)
obs_r=r;
obs_pi=pi;
obs_y=y;
obs_e=e;
obs_yw=yp/(-alpha*(2-alpha)*((1-tau)/tau));
end;


initval;
e=0;
pi=0;
piw=0;
q=0;
r=0;
y=0;
yp=0;
yw=0;
z=0;

end;
steady;
check;

shocks;
var eps_piw; stderr 0.15;
var eps_q; stderr 0.15;
var eps_r; stderr 0.15;
var eps_yw; stderr 0.15;
var eps_z; stderr 0.05;
end;

estimated_params;
alpha, beta_pdf,0.11,0.05;
kappa, gamma_pdf,0.32,0.25;
psi_1, gamma_pdf,1.3,0.5; 
psi_2, gamma_pdf,0.23,0.13;
psi_3, gamma_pdf,0.14,0.13;
r_ss, gamma_pdf,2.52,1; 
tau, beta_pdf,0.31,0.2;
rho_r, beta_pdf,0.69,0.2;
rho_q, beta_pdf,0.31,0.2;
rho_piw, beta_pdf,0.46,0.1;
rho_yw, beta_pdf,0.97,0.05;
rho_z, beta_pdf,0.42,0.05;
sigma_piw, inv_gamma_pdf,2,4;
sigma_r, inv_gamma_pdf,0.36,4;
sigma_q, inv_gamma_pdf,1.25,4;
sigma_yw, inv_gamma_pdf,1.29,4;
sigma_z, inv_gamma_pdf,0.84,4;
end;



varobs obs_e obs_pi obs_r obs_y obs_yw;

estimated_params_init(use_calibration);
end;

estimation(datafile=StationnaryData,xls_range=B1:F90,nobs=450,mode_compute=6,diffuse_filter,mh_replic=2000,mh_nblocks=2,mh_drop=0.45,mh_jscale=0.65);

%resid(1);
stoch_simul(order = 1,irf=120, hp_filter=1600)e pi piw q r y yp yw;
shock_decomposition pi r y z yw yp;