//Milani and Treadwell 2011//
//The effects of monetary policy "news" and "surprises"// 
//Table 3 page 11 
//------------------------------------------------------------------------
//       Variables and Parameters
//------------------------------------------------------------------------
var x pi i g mu v e_v; 

varexo e_g e_mu e_v4 e_v8 e_v12 e_mp e_vt; 


//------------------------------------------------------------------------
//       Parameter Values
//------------------------------------------------------------------------

parameters alpha rho_i phi_pi phi_x phi rho_v gamma beta theta w zeta epsilon upsilon delta eta tilda xi csi iota sigma rho_g rho_mu sigma_g sigma_mu sigma_v;
                                                                                                                                  
alpha = 0.898; //Calvo parameter//
phi_pi = 1.529; //MP Feedback Inflation//
phi_x = 0.359; //MP Feedback output gap//
phi = 0.909; //Habit formation//
gamma = 0.88; //Price indexation//
beta = 0.99;
theta=1/(1+phi);
w=2;
zeta=11;
upsilon=1/(1-phi);
epsilon = phi/(1+phi);
csi=1+(beta*gamma);
delta=beta/csi;
eta=gamma/csi;
sigma=1; 
tilda = sigma*(1-phi)/(1+phi);
xi=(1-alpha)*(1-(alpha*beta))/alpha;
iota=xi/csi;
rho_g = 0.426; //Inertia demand shock//
rho_mu = 0.037; //Inertia inflation shock//
rho_v = 0.236;//Inertia MP shock//
rho_i = 0.877; //Inertia monetary policy//
sigma_g = 0.275; //Std demand shock//
sigma_mu = 0.157; //Std inflation shock//
sigma_v = 0.078; //Std monetary policy shock//


model(linear);
x  = theta * x(-1)  + epsilon * x(+1) + tilda *( i - pi(+1) ) + g; 
pi = delta * pi(-1) + gamma*pi(+1) + iota*(w*x + upsilon*(x-phi*x(-1)))+ mu;
i = rho_i * i(-1)+(1-rho_i)*(phi_x*x + phi_pi*pi) + v;

//shock processes
g = rho_g*g(-1)+ e_g;
mu = rho_mu*mu(-1)+ e_mu;
v = rho_v*v(-1)+ e_v;
e_v = e_v4(-4) + e_v8(-8) +e_v12(-12) + e_mp;
end;


steady;
check;



shocks;
var e_g;
stderr 0.275;
var e_mu;
stderr 0.157;
var e_mp;
stderr 0.078;
var e_v4;
stderr 0.119;
var e_v8;
stderr 0.099;
var e_v12;
stderr 0.089;
var e_vt;
stderr 0.307;
end;




stoch_simul(periods=196,irf=24,order=1) x pi i e_v;