# Unit root variables

**URL:** <https://forum.dynare.org/t/unit-root-variables/6138>\
**Category:** Steady state\
**Created:** [12 April 2017 02:38 UTC](https://forum.dynare.org/t/unit-root-variables/6138 "2017-04-12T02:38:31Z")\
**Posts on this page:** 1\
**Showing post:** 2

<div class="post-metadata">

**Author:** ![jpfeifer](https://forum.dynare.org/user_avatar/forum.dynare.org/jpfeifer/32/5044_2.png) [@jpfeifer](https://forum.dynare.org/u/jpfeifer)\
**Post date:** [12 April 2017 08:26 UTC](https://forum.dynare.org/t/unit-root-variables/6138/2 "2017-04-12T08:26:17Z")

</div>

Hi,

pure non-stationary models have an infinity of steady states; non-stationary models with drift have none.

In Dynare, this creates a problem if you have a non-linear model where you need to compute a local approximation. In this case, you cannot endogenously compute _the steady state_, because there are many of them. You need to provide the steady state.

If your model is already linear, there should be no such problem, because the default initial value of 0 already is the steady state.

A simulation example of a model with unit root would be the standard local trend model:

```auto
var beta mu psi	tren slop cyc v;

varexo e_irr e_lev e_slp e_cyc;

parameters rho sdirr sdlev sdslp sdcyc;
	
rho = 0.75;   
sdirr = 0.005;  
sdlev = 0.0001; 
sdslp = 0.0001; 
sdcyc = 0.005; 

model(linear);
	mu	= mu(-1) + beta(-1) + sdlev*e_lev;
	beta =	beta(-1) + sdslp*e_slp;
	psi = rho*psi(-1) + sdcyc*e_cyc;
		
	tren =	mu(-1);
	
	slop =	beta(-2);
	
	cyc = psi(-1);
	
	v = tren + cyc + sdirr*e_irr;	
end;

shocks;
	var e_irr; stderr 1;
	var e_lev; stderr 1;
	var e_slp; stderr 1;
	var e_cyc; stderr 1;
end;

stoch_simul(order=1,irf=20,periods=200);

rplot tren cyc;
```

---

_[View the full topic](https://forum.dynare.org/t/unit-root-variables/6138)._
